Linhas de cabeçalho repetidas desaparecem depois que a tabela vinculada é atualizada no Word

Question

Estou tentando descobrir como impedir que o Word remova a opção "repetir como linha de cabeçalho no topo de cada página" quando uma tabela vinculada é atualizada no Word. Tenho ~ 300 tabelas vinculadas em um documento de várias fontes de dados, por isso, é preciso muito tempo para copiar e colar as tabelas no documento do Word toda vez.

Eu tentei selecionar a opção de linha de repetição na opção de configuração de página no Excel, mas isso também não parece funcionar.

Existe uma maneira que eu poderia copiar todas as tabelas no Excel programaticamente usando o VBA ou impedir que o Word exclua as propriedades da tabela sempre que as tabelas vinculadas forem atualizadas?

    

Answer 1

OK. Então fui em frente e escrevi uma macro que salvaria todas as propriedades de HeadingFormat para cada linha em cada tabela, atualizaria todas as tabelas e reaplicaria essas propriedades de formatação. A macro parece funcionar muito bem e deve ser utilizável para outras aplicações. Aproveite!

Public Sub UpdateTables()
'Get Table Formats
Dim i As Integer
Dim j As Integer

Dim tablecount As Integer
tablecount = ActiveDocument.Tables.Count

Dim tableformats() As Integer
ReDim tableformats(tablecount)

For i = 1 To tablecount
    j = 1
    Do While ActiveDocument.Tables(i).Rows(j).HeadingFormat = -1
        tableformats(i) = tableformats(i) + 1
        j = j + 1
    Loop
    'MsgBox (tableformats(i))
Next i

'Update Table References
ActiveDocument.Fields.Update

'Apply Table Formating to Updated Tables
For i = 1 To tablecount
    For j = 1 To tableformats(i)
        If ActiveDocument.Tables(i).Rows(j).HeadingFormat = 0 Then
            ActiveDocument.Tables(i).Rows(j).HeadingFormat = wdToggle
        End If
    Next j
Next i       
End Sub