arquivo BATCH para mesclar vários arquivos de texto e preservar nomes

Question

Eu tenho os seguintes arquivos de texto:

apple1.txt
apple2.txt
apple3.txt

water melon10.txt
water melon11.txt
water melon12.txt

Gostaria de mesclar todas as maçãs em um arquivo txt - apple_all.txt e todas as melancias em outra - water melon_all.txt

Observe que o espaço na melancia é proposital - alguns nomes de arquivos txt possuem espaços neles.

Todos os arquivos estão em uma pasta. A ordem de fusão é irrelevante.

    

Answer 1

MERGE.BAT

@echo off
>"%~1_all.txt" (
  for %%F in ("%~1*.txt") do if /i "%%F" neq "%~1_all.txt" type "%%F"
)

Uso:

merge apple
merge "water melon"

Ou, colocando tudo em um script em lote:

@echo off
call :merge apple
call :merge "water melon"
exit /b

:merge
>"%~1_all.txt" (
  for %%F in ("%~1*.txt") do if /i "%%F" neq "%~1_all.txt" type "%%F"
)
exit /b

Programaticamente, descobrir todas as frutas na pasta não é trivial, já que não há uma maneira fácil em lote de aparar todos os dígitos à direita do nome base de um arquivo. Aqui está uma vez solução (não testada):

@echo off
setlocal disableDelayedExpansion
del *_all.txt 2>nul
for /f "delims=" %%F in (
  'dir /b /a-d *.txt^|findstr "[^0-9][0-9]*\.txt$"'
) do call :proc "%%F"
exit /b

:proc
set "file=%~1"
set "fruit=%~n1"
setlocal enableDelayedExpansion
:trimNum
if "!fruit:~-1!" geq "0" if !fruit:~-1!" leq "9" (
  set "fruit=!fruit:~0,-1!"
  goto :trimNum
)
type "!file!" >>"!fruit!_all.txt"
exit /b