Como posso salvar vários textos separados com o AutoHotKey?

Question

Eu não sei se isso será possível, mas aqui está um exemplo para uma melhor ilustração.

Digamos que tenhamos uma pequena lista de palavras:

-house

-computador

- roupas

-humano

Digamos que podemos selecionar house usando ctrl + a. Agora, se quisermos selecionar a próxima palavra, pressionamos o botão tab, e depois novamente ctrl + a ..

Eu quero que cada palavra seja salva em algum lugar, então quando eu pressionar o botão f1, a casa será colada. Quando eu pressionar f2, o computador será colado, etc.

Quando cheguei a uma quantidade específica de palavras, quero que esvaziemos o "cache" ou qualquer nome que possa ser chamado: p

Isso é possível com o autohotkey? Eu tenho alguns conhecimentos básicos, mas isso é um pouco mais aventureiro imo.

    

Answer 1

; Create an object (array) to save the selected word (value) 
; each time you press your key (combination): 

MyArray := []
Index := 0
MaxIndex = 12       ; specific amount of words


; select next word and press your key (e.g. esc) to save the selected word in the array:

esc::
ClipSaved := ClipboardAll  ; save the entire clipboard to the variable ClipSaved
clipboard := "" ; empty clipboard
Send, ^c        ; copy the selected word
ClipWait 1      ; wait for the clipboard to contain data
If !ErrorLevel  ; If NOT ErrorLevel clipwait found data on the clipboard
{
    Index++     ; checks the number in the variable "Index" and increases it by 1, each time you press esc.
    if (Index = MaxIndex+1) ; when the specific amount of words is exceeded
    {
        Index := 1      ; set this variable to 1
        MyArray := []   ; recreate the object (empty the array)
    }
    MyArray.Insert(Index, clipboard)    
}
Sleep, 300
clipboard := ClipSaved  ; restore original clipboard
return

f1:: SendInput, % MyArray[1]
f2:: SendInput, % MyArray[2]
f12:: SendInput, % MyArray[12]

Para entender melhor todo o contexto, leia link