Excel 2010 Células específicas para argumentos de células de entrada de fórmulas

Question

     Col A  Col B  Col C
Row 1  a      a      a  
Row 2  a      a      a  
Row 3  a      a      a  

Estou tentando definir um intervalo específico na função COUNTIF, = COUNTIF (range, criteria).

Exemplo 1: Usando os dados de amostra acima, gostaria de ver quantas ocorrências da letra "a" na Linha 1, Coluna A. Isso pode ser feito simplesmente observando a célula única, A2.

=COUNTIF(A1,"a")

Exemplo 2: Gostaria de ver quantos "a" ocorrem em toda a Linha 2. Isso pode ser feito usando o intervalo de A2: C2.

=COUNTIF(A2:C2,"a")

Exemplo 3: Aqui é onde eu estou preso. Eu gostaria de ver quantos "a" ocorrem na Linha 3, Coluna A & C apenas. Não consigo descobrir como inserir isso na fórmula.

=COUNTIF(????????,"a")

EDITAR : Obrigado a todos pelas respostas rápidas. A razão pela qual fiz esta pergunta é porque estou realmente trabalhando no seguinte problema:

Eu inseri dados manualmente nas colunas A - H. Column A & B combinado cria uma das quatro classificações. Acampamento; D crie a segunda classificação. E & F crie o terceiro. G & H crie a quarta classificação. Eu combinei essas quatro classificações e são vistas nas colunas I - L. Dessas quatro classificações (de 25 combinações, podem ser repetidas) que aparecem em ordem diferente, eu preciso atribuir o valor mais alto (1 = alto, 4 = baixo ) na coluna N. A coluna M é uma coluna extra que eu precisava para completar as funções necessárias. Ele gera a classificação mais alta das quatro classificações como um número de 1 a 25 (o total de opções possíveis). A partir desse número, indexo a classificação correspondente da folha de classificação.

As fórmulas abaixo funcionam bem. A razão pela qual estou pedindo ajuda é por dois motivos. Eu quero combinar todo o trabalho em uma única célula (se possível) e remover as colunas adicionadas I - L, onde posso facilmente CONCATENAR () as duas entradas manuais por classificação dentro de uma função. Eu pensei que poderia ser feito, mas o que me prendia principalmente era a seção do código abaixo:

COUNTIF(I1:L1,Ratings!$A$1:$A$25)

Ele está me segurando porque COUNTIF () pode pegar um intervalo como um argumento de entrada, mas não células separadas. Eu quero ter (A1 e amp; B1), (C1 e D1), (E1 e F1), (G1 e H1) como a parte "range" do argumento para a função COUNTIF (). As classificações para cada combinação disponível estão na segunda folha chamada "Classificações".

Sheet 1: Sheet1

Columns: A  B  C  D  E  F  G  H  I  J  K  L  M  N
  Row 1: D  2  A  5  E  3  E  3  D2 A5 E3 E3   

Colunas A-H são inseridas manualmente.

A coluna I é (A1 e amp; B1)

A coluna J é (C1 e D1)

Coluna K é (E1 e F1)

A coluna L é (G1 e H1)

- Coluna M é

  {=IFERROR(MATCH(1,IF(COUNTIF(I1:L1,Ratings!$A$1:$A$25)>0,1,0),0),"")}

Coluna N é

   =IFERROR(INDEX(Ratings!$B$1:$B$25,M1),"")

A segunda folha com o rótulo Classificações está abaixo:

Sheet 2: Ratings
Columns: A   B
Row 1:   A5  1
Row 2:   A4  1
Row 3:   B5  1
Row 4:   A3  1
Row 5:   A2  1
Row 6:   B4  2
Row 7:   B3  2
Row 8:   C5  2
Row 9:   C4  2
Row 10:  D5  2
Row 11:  A1  3
Row 12:  B2  3
Row 13:  B1  3
Row 14:  C3  3
Row 15:  C2  3
Row 16:  D4  3
Row 17:  E5  3
Row 18:  C1  4
Row 19:  D3  4
Row 20:  D2  4
Row 21:  D1  4
Row 22:  E4  4
Row 23:  E3  4
Row 24:  E2  4
Row 25:  E1  4

Espero que com todo o problema em mãos, todos vocês possam entender melhor o que estou tentando realizar.

    

Answer 1

Encontrei uma solução melhor com a ajuda de um amigo. Consiste em substituir o método COUNTIF () por MIN (VLOOKUP (), VLOOKUP (), VLOOKUP (), VLOOKUP ()) para encontrar a classificação mais alta dos 4 valores fornecidos. Eu também fui capaz de concatenar as 2 colunas, eliminando assim as 4 colunas combinadas extras e a coluna "mid step" usando o método.

=MIN(VLOOKUP((A1&B1),Ratings!$A$1:$B$25,2,FALSE),VLOOKUP((C1&D1),Ratings!$A$1:$B$25,2,FALSE),VLOOKUP((E1&F1),Ratings!$A$1:$B$25,2,FALSE),VLOOKUP((G1&H1),Ratings!$A$1:$B$25,2,FALSE))

    

Answer 2

=countif(A3,"a")+countif(C3,"a")

ou mais simplesmente:

=(A3="a")+(C3="a")

Mesmo que você defina um Intervalo Nomeado que seja separado, COUNTIF() não o aceitará.

No entanto, algo como:

=SUMPRODUCT(COUNTIF(INDIRECT({"A3","C3"}),"a"))

funcionará, mas não é melhor que a soma de COUNTIF() s.

    

Answer 3

Aqui estão algumas outras opções:

Isso é baseado no número do índice:

=SUM(INDEX(((COLUMN(A3:C3) = 1)+(COLUMN(A3:C3) =3))*(A3:C3="a"),))

Isso é baseado em um padrão de todos os outros:

=SUM(INDEX((MOD(COLUMN($A$3:$C$3),2)=1)*($A$3:$C$3="a"),))

Isso é baseado nos valores da Linha 1:

=SUM(INDEX(($A$1:$C$1="Yes")*($A$3:$C$3="a"),))