HTML A assinatura de e-mail nem sempre é exibida

Question

Eu tenho uma assinatura de email em HTML. Não mostrava o tempo todo, porque às vezes as pessoas respondem em texto simples. Então minhas respostas também estão em texto puro.

Então eu encontrei uma macro na internet que envia todos os meus e-mails em HTML. Aparentemente você não deveria fazer isso, mas desde que eu enviei todos os novos emails em HTML eu não consigo ver porque não.

No entanto, agora, em vez de serem texto simples, eles são HTML, mas sempre em Times New Roman, e a assinatura não mostra o logotipo, apenas o texto, mas não formatado. Alguém sabe como resolver esse problema?

Obrigado antecipadamente

    

Answer 1

Acabei de usar este artigo para atualizar minha macro.

link

Sub ForceReplyInHTML()

    '=================================================================
    'Description: Outlook macro to reply to a message in HTML
    '             regardless of the current message format.
    '             The reply will use your HTML signature as well.
    '
    'author : Robert Sparnaaij
    'version: 1.0
    'website: http://www.howto-outlook.com/howto/replyinhtml.htm
    '=================================================================

        Dim objOL As Outlook.Application
        Dim objSelection As Outlook.Selection
        Dim objItem As Object
        Set objOL = Outlook.Application

        'Get the selected item
        Select Case TypeName(objOL.ActiveWindow)
            Case "Explorer"
                Set objSelection = objOL.ActiveExplorer.Selection
                If objSelection.Count > 0 Then
                    Set objItem = objSelection.Item(1)
                Else
                    Result = MsgBox("No item selected. " & _
                                "Please make a selection first.", _
                                vbCritical, "Reply in HTML")
                    Exit Sub
                End If

            Case "Inspector"
                Set objItem = objOL.ActiveInspector.CurrentItem

            Case Else
                Result = MsgBox("Unsupported Window type." & _
                            vbNewLine & "Please make a selection" & _
                            " or open an item first.", _
                            vbCritical, "Reply in HTML")
                Exit Sub
        End Select

        Dim olMsg As Outlook.MailItem
        Dim olMsgReply As Outlook.MailItem
        Dim IsPlainText As Boolean

        'Change the message format and reply
        If objItem.Class = olMail Then
            Set olMsg = objItem
            If olMsg.BodyFormat = olFormatPlain Then
                IsPlainText = True
            End If
            olMsg.BodyFormat = olFormatHTML
            Set olMsgReply = olMsg.Reply
            If IsPlainText = True Then
                olMsg.BodyFormat = olFormatPlain
            End If
            olMsg.Close (olSave)
            olMsgReply.Display

        'Selected item isn't a mail item
        Else
            Result = MsgBox("No message item selected. " & _
                        "Please make a selection first.", _
                        vbCritical, "Reply in HTML")
            Exit Sub
        End If

        'Cleanup
        Set objOL = Nothing
        Set objItem = Nothing
        Set objSelection = Nothing
        Set olMsg = Nothing
        Set olMsgReply = Nothing

    End Sub

Eu recriou a macro três vezes, uma para avançar, uma para responder, uma para responder a todas, renomei-as na parte superior Sub ForceReplyInHTML para criar as três macros diferentes.

Também usei os artigos relacionados nesse link para criar botões e assinar minhas macros. No estágio final, usei o botão Modificar para alterar os ícones das minhas Macros para facilitar a lembrança de qual delas fez qual.