Remover um contato de grupos de contatos no outlook

Question

Recentemente, uma colega se demitiu de nossa empresa e eu preciso excluí-la do todos os grupos de contato do meu Outlook.
Qualquer sugestão será apreciada!
Existe uma maneira fácil de fazer isso?

    

Answer 1

A exclusão de um contato de todos os grupos requer uma macro VBA.

Essa macro é detalhada no artigo Como remover rapidamente um contato específico de todos os grupos de contatos via Outlook VBA .

O artigo detalha como essa macro é instalada por meio do Guia Desenvolvedor / Visual Basic, e depois pode ser executado através do Executar ícone na barra de ferramentas.

Caso esse artigo desapareça mais tarde, a macro VBA será detalhada aqui:

Sub RemoveSpecificContactfromAllGroups()
    Dim strSpecificContact As String
    Dim objTempMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objContactsFolder As Outlook.Folder
    Dim objItem As Object
    Dim objContactGroup As Outlook.DistListItem
    Dim objContact As Outlook.ContactItem
    Dim nprompt As Integer

    strSpecificContact = InputBox("Input the fullname or email address of the specific contact to be removed from all contact groups:")
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
    Set objRecipient = objTempMail.Recipients.Add(strSpecificContact)
    objRecipient.Resolve

    If objRecipient.Resolved = True Then
       Set objContactsFolder = Outlook.Application.Session.GetDefaultFolder(olFolderContacts)
       For Each objItem In objContactsFolder.Items
           If TypeOf objItem Is DistListItem Then
              Set objContactGroup = objItem
              With objContactGroup
                   .RemoveMember objRecipient
                   .Body = "Contact Removed: " & strSpecificContact & vbTab & "(" & Now & ")" & .Body
                   .Save
              End With
           End If
       Next
       nprompt = MsgBox("Removing Completes!", vbExclamation, "Remove Contact from Group")
    Else
       nprompt = MsgBox("This contact cannot be resolved!", vbExclamation, "Resolving Error")
    End If
End Sub