Como você copia os códigos de campos brutos do Microsoft Word para outro documento de texto?

Question

É possível copiar texto de um documento do Word que contenha códigos de campo, de modo que, quando forem introduzidos em outro aplicativo, os CÓDIGOS DE CAMPO CONTINHAM COMO TEXTO RAW. ou seja, algo como

This is about whales { XE "Cetations:Whales" }. This is about dolphins { XE "Cetations:Dolphins" }.

em vez de remover os códigos de campo?

    

Answer 1

Adicione macro ao documento, selecione o texto, execute a macro, agora você pode copiar os códigos dos campos para a área de transferência.

no escritório 2010 ALT + F9 é usado para exibir códigos de campos.

Sub StuffFieldCode()
    Dim sField As String
    Dim sTextCode As String
    Dim bSFC As Boolean
    Dim MyData As DataObject
    Dim sTemp As String
    Dim J As Integer

    Application.ScreenUpdating = False

    If Selection.Fields.Count = 1 Then
        bSFC = Selection.Fields.Item(1).ShowCodes
        Selection.Fields.Item(1).ShowCodes = True
        sField = Selection.Text
        sTextCode = ""
        For J = 1 To Len(sField)
            sTemp = Mid(sField, J, 1)
            Select Case sTemp
                Case Chr(19)
                    sTemp = "{"
                Case Chr(21)
                    sTemp = "}"
                Case vbCr
                    sTemp = ""
            End Select
            sTextCode = sTextCode & sTemp
        Next J

        Set MyData = New DataObject
        MyData.SetText sTextCode
        MyData.PutInClipboard

        Selection.Fields.Item(1).ShowCodes = bSFC
    End If

    Application.ScreenUpdating = True
End Sub

    

Answer 2

Pressione Alt + F9 para mostrar o código do campo, então destaque todo o texto dentro das chaves {}. Você pode copiar e colar este texto.

Aqui está um link para uma macro que alguém escreveu para fazer todo o trabalho: Copiar e colar códigos de campo