Engraçado, eu usei todas as 3 respostas até agora;)
Aqui está outra opção: use o applescript. Você pode criar scripts de macacos que abrem uma janela no diretório do localizador atual, por exemplo.
Eu tenho um monte de applescripts assim e eu os amarrei a hotkeys com Quicksilver (ou mordomo)
por padrão, eu uso um atalho que abre um terminal no diretório do localizador atual, mas apenas se o finder for o aplicativo mais avançado. Caso contrário, eu simplesmente recebo uma janela nova.
Então eu também tenho scripts que abrem sessões ssh para certos servidores e reconectar a uma sessão de tela. Com a opção -x para a tela, você pode ter várias janelas erminal procurando no mesmo terminal de servidor, ótimo:)
EDITAR:
Este é o script que eu escrevi que abre uma nova janela, indo para o diretório atual do Finder se o Finder for o aplicativo atualmente ativo:
on run
-- Figure out if we want to do the cd (doIt)
-- Figure out what the path is and quote it (myPath)
try
tell application "Finder" to set doIt to frontmost
set myPath to finder_path()
if myPath is equal to "" then
set doIt to false
else
set myPath to quote_for_bash(myPath)
end if
on error
set doIt to false
end try
-- Figure out if we need to open a window
-- If Terminal was not running, one will be opened automatically
tell application "System Events" to set isRunning to (exists process "Terminal")
tell application "Terminal"
-- Open a new window
if isRunning then do script ""
activate
-- cd to the path
if doIt then
-- We need to delay, terminal ignores the second do script otherwise
delay 0.3
do script "cd " & myPath in front window
end if
end tell
end run
on finder_path()
try
tell application "Finder" to set the source_folder to (folder of the front window) as alias
set thePath to (POSIX path of the source_folder as string)
on error -- no open folder windows
set thePath to ""
end try
return thePath
end finder_path
-- This simply quotes all occurrences of ' and puts the whole thing between 's
on quote_for_bash(theString)
set oldDelims to AppleScript's text item delimiters
set AppleScript's text item delimiters to "'"
set the parsedList to every text item of theString
set AppleScript's text item delimiters to "'\''"
set theString to the parsedList as string
set AppleScript's text item delimiters to oldDelims
return "'" & theString & "'"
end quote_for_bash
Para usá-lo, abra o Script Editor e cole-o. Em seguida, salve-o em algum lugar conveniente (eu uso ~ / Library / Scripts) e diga QuickSilver, Butler ou Google Quick Search Bar para executá-lo. Com o QS e o Butler, você também pode definir teclas de atalho globais.
Espero que isso ajude,
Wout.