Como configurar o grupo de trabalho para receber atualizações do WSUS

Question

Oi pessoal Eu tenho servidor WSUS e está funcionando bem com diectory ativo. mas como posso conectar PCs do grupo de trabalho em execução no windows xp ao WSUS sem conectá-los ao AD? Obrigado antecipadamente.

    

Answer 1

Eu uso o seguinte script em lote para ativar e desativar os sistemas flip-flop no WSUS. Funciona muito bem para atualizar rapidamente os sistemas formatados antes de fornecê-los.

Altere [SERVER] para o servidor do WSUS na seção :USEWSUS .

@echo off
:START
cls
echo Temporary WSUS Script
echo ==============================
echo This script will flip between using the internal WSUS server and Microsoft's servers.
echo.
set /p WSUSSETTING=Type [W] to use WSUS or [C] to clear the setting and use MS servers: 

IF /i (%WSUSSETTING%) == (W) goto CONTINUE
if /i (%WSUSSETTING%) == (C) goto CONTINUE

echo.
echo Error: Invalid selection
pause
goto START

:CONTINUE
echo Stopping Update Services...
net stop wuauserv
echo Deleting timeout registry entries (Safe to ignore errors)...
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v LastWaitTimeout /f
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v DetectionStartTime /f
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v NextDetectionTime /f

IF /i (%WSUSSETTING%) == (W) goto USEWSUS
IF /i (%WSUSSETTING%) == (C) goto USEMS

:USEWSUS
echo Changing update server to local WSUS server...
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUServer /t REG_SZ /d "http://[SERVER]:8530" /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUStatusServer /t REG_SZ /d "http://[SERVER]:8530" /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v NoAutoUpdate /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v AUOptions /t REG_DWORD /d 3 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v AutoInstallMinorUpdate /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v UseWUServer /t REG_DWORD /d 1 /f
goto COMPLETE

:USEMS
echo Clearing WSUS update server...
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUServer /f
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUStatusServer /f
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v UseWUServer /f
goto COMPLETE


:COMPLETE
echo Starting Update Services...
net start wuauserv

:END
echo ---
echo Complete.
pause

    

Answer 2

Você pode fazer as mesmas alterações necessárias atualizando o registro diretamente; uma pesquisa rápida me levou a este link que parece ter as informações corretas. Se não, uma pesquisa mais minuciosa da sua parte provavelmente lhe dará a informação que você está perdendo.

    

Answer 3

Se for Professional Edition, você também pode usar a Diretiva de Grupo local. Execute gpedit.msc e navegue até "Configuração do computador - > Modelos administrativos - > Componentes do Windows - > Atualização do Windows".