Colocando atalhos nas máquinas dos usuários usando AD

Question

Acabei de lidar com uma pequena tarefa, que gostaria de automatizar por meio do Active Directory. Escrevemos alguns aplicativos de intranet que são muito usados aqui. Ocasionalmente alguém terá que ir até a recepção e trabalhar em alguma coisa lá, enquanto uma das recepcionistas está ausente. Eles sempre nos ligam para nos colocar um atalho em sua área de trabalho com links para esses aplicativos da Intranet. É um incômodo, e tenho certeza de que o AD pode ser usado para automatizar a criação de atalhos nos desktops dos usuários que apontam para nossos aplicativos de intranet. A única coisa é, eu não sei como fazer isso, e sendo uma pequena loja que somos, não temos um administrador de sistema no momento.

Então, como automatizar a criação de atalhos na área de trabalho para sites, usando o AD em um ambiente Windows 2003 Server?

    

Answer 1

Com o Windows Server 2003, você não pode se dar ao luxo das ferramentas integradas da Diretiva de Grupo, que oferecem uma boa GUI para criar e implantar atalhos. Você tem que usar o VBScript para adicionar os atalhos.

Aqui está uma que eu usei antes -

' AddDesktopShortcut - adds a desktop shortcut if one does not exist.
' 
' first argument = URL or path to desktop application
' second argument = Name of the shortcut
' third argument = path to the icon to use; this must include the icon index as well, e.g.
'                  "C:\windows\system32\shell32.dll,15". Pass an empty string, i.e. "" to
'                  use the default icon instead.

' repeat these lines for as many shortcuts as you want.
AddDesktopShortcut "http://www.google.com", "Google", ""
AddDesktopShortcut "http://www.bing.com", "Bing", "C:\Windows\System32\shell32.dll,13"

Sub AddDesktopShortcut (ByVal path, ByVal name, ByVal iconPath)
    Dim objFSO, objShell, strDesktop, objLink, strLinkPath

    Set objFSO = CreateObject("Scripting.FileSystemObject")

    Set objShell = CreateObject("WScript.Shell")
    strDesktop = objShell.SpecialFolders("Desktop")

    strLinkPath = strDesktop & "\" & name & ".lnk"
    If Not objFSO.FileExists(strLinkPath) Then
        ' shortcut doesn't exist, create it
        Set objLink = objShell.CreateShortcut(strLinkPath)
        objLink.Description = name
        If Len(iconPath) > 0 Then 
            objLink.IconLocation = iconPath 
        Else 
            ' change this line to change the default icon
            objLink.IconLocation = "C:\Windows\System32\shell32.dll,14"
        End If
        objLink.TargetPath = path
        objLink.Save
    End If

    ' clean up
    Set objLink = Nothing
    Set objShell = Nothing
    Set objFSO = Nothing
End Sub

Modifique o script para adicionar os atalhos necessários; o script acima adiciona dois atalhos aos desktops do usuário, um para o Google e outro para o Bing.

Depois de modificar o script, no servidor, acione a ferramenta Gerenciamento de Diretiva de Grupo (Iniciar - > Painel de Controle - > Ferramentas Administrativas - > Gerenciamento de Diretiva de Grupo). Você pode usar uma política de grupo existente ou criar uma nova apenas para essa finalidade. A menos que você já tenha montes de objetos de Política de Grupo, é provavelmente mais fácil criar um novo.

Localize a unidade organizacional (UO) ou o domínio na árvore que contém os usuários / computadores aos quais você deseja adicionar os atalhos, clique com o botão direito do mouse e selecione "Criar um novo GPO neste domínio e vinculá-lo aqui. "(parafraseada - eu não tenho uma caixa de servidores Win2003 na minha frente no momento).

Nomeie esse GPO, clique com o botão direito e selecione Editar. Em seguida, vá para Configuração do usuário - > Políticas - > Configurações do Windows - > Scripts - > Logon na árvore. Clique com o botão direito sobre isso, clique em Propriedades. A partir daí, clique no botão Show Files e copie o arquivo de script para lá. Em seguida, retorne à caixa de diálogo Logon Properties, clique em Add e insira / navegue até o arquivo de script. Clique em OK, feche a janela Editor de Gerenciamento de Diretiva de Grupo e você deve estar certo.

Você pode usar a ferramenta de Modelagem de Diretiva de Grupo para ver onde esse GPO será aplicado (se você acabou de seguir as instruções aqui, ele será aplicado a todos os usuários na UO / domínio selecionado - você pode usar segurança grupos ou vinculá-lo a outras OUs para ser mais específico); ou use a ferramenta Resultados da Diretiva de Grupo para ver onde ela foi aplicada.