Não é realmente o lugar para soluções baseadas em código (veja Stack Overflow), mas eu vou morder:
Primeiro, eu assumo uma tabela chamada logins, com os seguintes dados ...
IF OBJECT_ID('tempdb..logins') IS NOT NULL DROP TABLE logins;
GO
CREATE TABLE logins (userID INT, startTime DATETIME, endTime DATETIME)
GO
INSERT INTO logins (userID, startTime, endTime)
VALUES (101, '2013-11-04T11:00:00', '2013-11-04T11:00:00')
,(102, '2013-11-04T11:00:00', '2013-11-04T11:24:00')
,(103, '2013-11-04T11:20:00', '2013-11-04T11:45:00')
,(104, '2013-11-04T11:30:00', '2013-11-04T11:35:00')
,(105, '2013-11-04T11:40:00', '2013-11-04T11:55:00');
GO
Se você quer apenas saber em que período de 10min um login se encaixa, uma maneira simples (embora mágica) seria usar a data zero ...
SELECT
period_start = DATEADD(MINUTE, DATEDIFF(MINUTE, 0, l.startTime) / 10 * 10, 0),
l.*
FROM logins l
GO
... para contagens simples, com base no período ...
WITH starts AS (
SELECT
period_start = DATEADD(MINUTE, DATEDIFF(MINUTE, 0, l.startTime) / 10 * 10, 0),
l.*
FROM logins l
)
SELECT
period_start,
login_count = COUNT(1)
FROM starts
GROUP BY period_start
GO
No entanto, se você quiser mostrar também as lacunas de contagem 0, precisará de uma função para obter todas as datas e, em seguida, juntá-las à esquerda ...
-- periods: a table-function to get a series of date/times intervals between two dates
-- (tally approach taken from Itzik Ben-Gan's article http://sqlmag.com/sql-server/virtual-auxiliary-table-numbers)
IF OBJECT_ID('tempdb..periods') IS NOT NULL DROP FUNCTION periods;
GO
CREATE FUNCTION periods(
@start_date DATETIME2,
@end_date DATETIME2 = GETDATE,
@incr_mins INT = 10
)
RETURNS TABLE
AS RETURN (
WITH
E1(N) AS (
SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1
), -- 10^1 or 10 rows
E2(N) AS (SELECT 1 FROM E1 a, E1 b), -- 10^2 or 100 rows
E4(N) AS (SELECT 1 FROM E2 a, E2 b), -- 10^4 or 10,000 rows
E8(N) AS (SELECT 1 FROM E4 a, E4 b), -- 10^8 or 100,000,000 rows
E16(N) AS (SELECT 1 FROM E8 a, E8 b), -- 10^16 or 10,000,000,000,000,000 rows
E32(N) AS (SELECT 1 FROM E16 a, E16 b), -- 10^32 or 100,000,000,000,000,000,000,000,000,000,000 rows
E64(N) AS (SELECT 1 FROM E32 a, E32 b), -- 10^64 or 10,000,000,000,000,000,000,000,000,000,000,000,000,000,000,000,000,000,000,000,000,000 rows
starts AS (
SELECT TOP (CEILING(ABS(DATEDIFF(MINUTE, @start_date, @end_date)) / @incr_mins))
period_start = DATEADD(MINUTE,
@incr_mins * (ROW_NUMBER() OVER (ORDER BY (SELECT 1)) - 1),
@start_date)
FROM E64
),
ends AS (
SELECT
period_start,
period_end = DATEADD(MINUTE, @incr_mins, period_start)
FROM starts
)
SELECT period_start, period_end
FROM ends
)
GO
Agora você pode usar o recurso para registrar seus logins nos períodos ...
SELECT
p.period_start,
login_count = SUM(CASE WHEN l.userID IS NULL THEN 0 ELSE 1 END)
FROM periods('2013-11-04T00:00:00', '2013-11-05T00:00:00', 10) p
LEFT JOIN logins l ON
l.startTime >= p.period_start AND
l.startTime < p.period_end
GROUP BY p.period_start
GO
Observe que chamar a função é um pouco mais caro, por isso, talvez seja melhor preencher uma tabela de 'calendário' bem indexada que pré-calcule todos os seus períodos e, em vez disso, associe-se a ela.
Espero que isso ajude.
J