Como calcular o percentual de cada coluna?

Question

Estou tentando transformar alguns dados em uma porcentagem do total de cada coluna, muito semelhante a esse segmento, exceto que preciso fazer isso para cada coluna: Calcule e divida por total com AWK

Os dados gostariam de algo assim (mas mais colunas e linhas):

ID     Sample1     Sample2      Sample3
One      10          0            5
Two      3           6            8
Three    3           4            7

E o resultado desejado ficaria assim:

ID     Sample1     Sample2     Sample3
One     62.50        0.0        25.0
Two     18.75       60.0        40.0
Three   18.75       40.0        35.0   

O seguinte funciona para uma única coluna, mas eu quero fazer isso para cada coluna, exceto a primeira.

gawk -F"\t" '{a[NR]=$1;x+=(b[NR]=$2)}END{while(++i<=NR)print a[i]"\t"100*b[i]/x}' file.txt 

Muito obrigado por qualquer ajuda que você possa ter.

    

Answer 1

Não 100% da mesma saída que você pediu, mas esperamos que feche o suficiente:

function percent(value, total) {
    return sprintf("%.2f", 100 * value / total);
}
{
    label[NR] = $1
    for (i = 2; i <= NF; ++i) {
        sum[i] += col[i][NR] = $i
    }
}
END {
    title = label[1]
    for (i = 2; i <= length(col) + 1; ++i) {
        title = title "\t" col[i][1];
    }
    print title
    for (j = 2; j <= NR; ++j) {
        line = label[j]
        for (i = 2; i <= length(col) + 1; ++i) {
            line = line "\t" percent(col[i][j], sum[i]);
        }
        print line
    }
}

Produz saída:

ID    Sample1 Sample2 Sample3
One   62.50   0.00    25.00
Two   18.75   60.00   40.00
Three 18.75   40.00   35.00

Execute com gawk -f script.awk file.txt

Claro, você poderia achatar o script em uma única linha, mas acho melhor mantê-lo em um arquivo de script assim, para facilitar a leitura e a manutenção.

Uma versão mais simples e melhor que funciona com o BSD AWK também, não apenas o GNU AWK:

function percent(value, total) {
    return sprintf("%.2f", 100 * value / total)
}
BEGIN { OFS = "\t" }
NR == 1 { gsub(/ +/, OFS); print; next }
{
    label[NR] = $1
    for (i = 2; i <= NF; ++i) {
        sum[i] += col[i, NR] = $i
    }
}
END {
    for (j = 2; j <= NR; ++j) {
        $1 = label[j]
        for (i = 2; i <= NF; ++i) {
            $i = percent(col[i, j], sum[i])
        }
        print
    }
}