Como obter o proprietário do arquivo no AIX sem importar a saída ls?

Question

Como posso confiantemente obter o proprietário de um arquivo no AIX? Por confiável, não quero analisar a saída de ls . No Linux, eu faria apenas um stat --printf=%U foo , mas estou trabalhando no AIX 6.1 e 7.1. Eu sei que posso fazer istat , mas como não há --printf opção no AIX istat , eu ainda teria que munge a saída com grep e awk , portanto, não tão desejável. Em outras palavras, como posso emular o stat --printf=%U foo do Linux usando apenas os principais utilitários do AIX?

    

Answer 1

Este é um script que escrevi há algum tempo, para obter um utilitário semelhante a stat (1) no AIX. Acabou de adicionar% U! Eu achei mais útil usar a opção -c, que se comporta de maneira ligeiramente diferente do --printf. Inclui uma cópia local acessível do array stat do perl como um bloco de comentário.

#!/usr/bin/env perl -w
# emulate GNU coreutils stat command in a limited way
# -- only implemented a subset of the stat() options

use strict;
use Getopt::Std;
our $opt_c;

getopts('c:') or die "Usage: $0 [ -c (%n %i %u %g %s %U %X %Y %Z) ] file ...";
# default format is empty (not useful, but avoids 'undef' errors later)
$opt_c |= '';

for (@ARGV) {
  my @s = stat;
  next unless @s; # silently fail on to the next file
  my $p = $opt_c; # make a copy of the format string to mangle for each file

  # mangle and print
  $p =~ s/%n/$_/g;
  $p =~ s/%i/$s[1]/g;
  $p =~ s/%u/$s[4]/g;
  $p =~ s/%g/$s[5]/g;
  $p =~ s/%s/$s[7]/g;
  $p =~ s/%U/getpwuid($s[4])/eg;
  $p =~ s/%X/$s[8]/g;
  $p =~ s/%Y/$s[9]/g;
  $p =~ s/%Z/$s[10]/g;
  print "$p\n";

  #                 0 dev      device number of filesystem
  #                 1 ino      inode number
  #                 2 mode     file mode  (type and permissions)
  #                 3 nlink    number of (hard) links to the file
  #                 4 uid      numeric user ID of file's owner
  #                 5 gid      numeric group ID of file's owner
  #                 6 rdev     the device identifier (special files only)
  #                 7 size     total size of file, in bytes
  #                 8 atime    last access time in seconds since the epoch
  #                 9 mtime    last modify time in seconds since the epoch
  #                10 ctime    inode change time in seconds since the epoch (*)
  #                11 blksize  preferred block size for file system I/O
  #                12 blocks   actual number of blocks allocated

}