Vlookup com valores duplicados por meio do AWK

Question

É necessário fazer uma busca em dois arquivos diferentes com entradas duplicadas:

Arquivo 1

abc     10
xyz     20
bhy     30
hgf     40

Arquivo 2

a   abc     
b   xyz     
c   bhy     
d   abc     
e   abc     
f   xyz     

Saída exigida:

abc     10  a,d,e
xyz     20  b,f
bhy     30  c
hgf     40  Not_Available

    

Answer 1

Awk solução:

awk 'NR == FNR { a[$1] = $2 OFS; next }
     $2 in a { a[$2] = a[$2] (a[$2] ~ /\t$/? "" : ",") $1 }
     END { for (i in a) print i, a[i] }' OFS='\t' file1 file2

A saída:

bhy 30  c
abc 10  a,d,e
xyz 20  b,f

Para sua última condição, use a seguinte modificação:

awk 'NR == FNR { a[$1] = $2 OFS; next }
     $2 in a { a[$2] = a[$2] (a[$2] ~ /\t$/? "" : ",") $1 }
     END {
         for (i in a) print i, a[i] (a[i] ~ /\t$/? "Not_Available" : "")
     }' OFS='\t' file1 file2

    

Answer 2

com o awk

awk -v OFS='\t' '
    NR == FNR {val[$1]=$2; next} 
    {items[$2] = items[$2] " " $1}
    END {
        for (a in val) {
            sub(/^ /, "", items[a])
            gsub(/ /, ",", items[a]) 
            print a, val[a], items[a]
        }
    }
' file1 file2

bhy     30      c
abc     10      a,d,e
xyz     20      b,f

Se você quiser, classifique em | sort -k2,2n

Apenas por diversão, um pouco complicado de perl

perl -lae '
    if ($. == ++$nr) { $val{$F[0]} = $F[1] }
    else             { push @{$items{$F[1]}}, $F[0] }
  } continue {
    close ARGV if eof
  } END { 
    printf "%s\t%s\t%s\n", $_, $val{$_}, join(",", @{$items{$_}}) for keys %items 
' file1 file2