vimdiff: Pula para a próxima diferença dentro da linha?

Question

vimdiff é muito útil para comparar arquivos. No entanto, eu costumo usá-lo em arquivos com linhas longas e relativamente poucas diferenças dentro das linhas.

O vimdiff realçará corretamente as diferenças dentro de uma linha (toda a linha rosa, diferentes caracteres em vermelho). Nestes casos, seria bom poder saltar para a próxima diferença dentro da linha .

Você pode pular para a "próxima diferença" (] c ), mas isso saltará para a próxima linha com uma diferença.

Existe uma maneira de ir para o próximo personagem diferente dentro da linha atual?

    

Answer 1

Eu vejo duas soluções:

1. você teria que testar o destaque da sintaxe atual para pular para a parte vermelha na linha.
2. você teria que extrair a linha atual nos dois buffers e encontrar o primeiro caractere que difere para posicionar corretamente o cursor

Ambas as soluções precisam ser executadas após o] c e requerem o script vim.

EDITAR: Aqui está um primeiro rascunho que parece funcionar:

nnoremap <expr> <silent> <F3>   (&diff ? "]c:call \<sid>NextDiff()\<cr>" : ":cn\<cr>")

function! s:GotoWinline(w_l)
  normal! H
  while winline() < a:w_l
    normal! j
  endwhile
  " todo: beware of cases where the window is too little
endfunction

" Better ]c, [c jump
function! s:NextDiff()
  if ! &diffopt =~ 'filler' | return | endif

  let ignore_blanks = &diffopt =~ 'iwhite'

  " Assert: called just after a ]c or a [c
  " Forces the cursos to be synchronized in all synced windows
  " let diff_l = line()
  try 
    let foldenable = &foldenable
    set nofoldenable

    let w_l = winline() " problematic with enabled lines (from diff...)
    " echomsg w_l.'|'.line('.').'|'.getline('.')

    let lines = {}
    windo if &diff | call <sid>GotoWinline(w_l) | let lines[winnr()]={'text':getline('.'), 'number':line('.')} | endif
  finally
    let &foldenable = foldenable
  endtry

  " echomsg string(lines)
  if len(lines) < 2 | return | endif

  let indices = repeat([0], len(lines))
  let tLines = values(lines)
  let found = 0
  " infinite loop on two empty texts...
  while ! found
    let c = ''
    let next_idx = []
    let i = 0
    while i != len(indices)
      let crt_line = tLines[i].text
      let n = indices[i]
      if len(crt_line) == n
    let found = 1
    break
      endif

      let c2 = (len(crt_line) == n) ? 'EOL' : crt_line[n]
      if empty(c) 
    let c = c2
      endif

      " checks match
      let n += 1
      if c =~ '\s'
    if (c2 != c) && (ignore_blanks && c2 !~ '\s')
      let found = 1
      break
    else " advance
      while ignore_blanks && (n == len(crt_line) || crt_line[n] =~ '\s')
        let n += 1
      endwhile
    endif
      else
    if c2 != c
      let found = 1
      break
    endif
      endif
      let next_idx += [n]

      let i += 1
    endwhile
    if found | break | endif

    let indices = next_idx
  endwhile

  " now goto the right column
  let windows = keys(lines)
  " Assert len(windows) == len(indices)
  let w = 0
  while w != len(windows)
    " echomsg 'W#'.windows[w].' -> :'(tLines[w].number).'normal! '.(indices[w]+1).'|'
    exe windows[w].'wincmd w'
    silent! exe (tLines[w].number).'normal! 0'.(indices[w]).'l'
    let w += 1
  endwhile
  " echomsg string(indices)
endfunction

    

Answer 2

Esta é uma solução fácil:

Você pode usar set wrap .

Isso criará problemas se a diferença causar quebra de texto em um número desigual de linhas.

    

Answer 3

Também não consigo descobrir como fazer isso com vimdiff , mas você pode conferir wdiff em vez disso. Ele mostra diferenças entre dois arquivos, uma palavra por vez.

Eu tive que compilá-lo a partir da fonte:

curl http://ftp.gnu.org/gnu/wdiff/wdiff-1.2.1.tar.gz > wdiff-1.2.1.tar.gz
tar -xzvf wdiff-1.2.1.tar.gz
cd wdiff-1.2.1
./configure
make
make install

    

Answer 4

A julgar pela documentação, isso não pode ser feito.