Excel - Excluir palavra específica em cada linha?

Question

Existe uma maneira de o Excel excluir uma palavra específica em cada linha? Por exemplo, cada linha diz o Sr. e a Sra. {Primeiro nome} {sobrenome} e eu quero excluir o {primeiro nome} de cada um. (Ou alternativamente, extraindo as três primeiras palavras e a última palavra e depois combinando-as.)

Obrigado!

    

Answer 1

Aqui está a minha solução. Que usa em parte este .

=LEFT(A6,FIND(" ",A6,FIND(" ",A6,FIND(" ",A6)+1)+1))&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ","")))))

Isso mantém as primeiras 3 palavras e a última palavra e não precisa presumir que as primeiras três palavras são "Mr. and Mrs.". Se você supuser que pode usar a versão mais curta:

="Mr. and Mrs. "&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ","")))))

Editar : usando minha fórmula principal e esta (que apenas fornece a primeira e a última palavra):

=LEFT(A6,FIND(" ",A6))&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ","")))))

Podemos combiná-los com uma declaração if ... Não sei qual declaração seria a melhor, mas deixe-me mostrar a você como seria a contagem de "." na declaração. Se for 2 ou maior, use as 3 primeiras palavras e a última, senão a primeira e a última palavra.

IF(LEN(A6)-LEN(SUBSTITUTE(A6,".",""))>=2,LEFT(A6,FIND(" ",A6,FIND(" ",A6,FIND(" ",A6)+1)+1))&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ",""))))),LEFT(A6,FIND(" ",A6))&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ",""))))))

Edit2: Se você quiser usar sua solução -and, você pode usar esta fórmula:

=LEFT(A6,FIND(" ",SUBSTITUTE(A6," and ","-and-")))&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ","")))))

    

Answer 2

Aqui está a fórmula para encontrar a terceira palavra, mas é longa:

=MID(MID(MID(SUBSTITUTE(A1," ","^",3),1,256),FIND("^",SUBSTITUTE(A1," ","^",3)),256),2,FIND(" ",MID(MID(SUBSTITUTE(A1," ","^",3),1,256),FIND("^",SUBSTITUTE(A1," ","^",3)),256))-2)

Link de referência aqui .

Agora, coloque isso em uma coluna, clique e arraste e crie uma segunda coluna que remova essa palavra.

Na verdade, no seu caso específico, você pode usar essa fórmula. Nesse exemplo, A1 tem a string e C1 é onde a fórmula acima é:

=LEFT(A1, 13) & RIGHT(A1,LEN(A1) - (13 + LEN(C1)))

E, é claro, você pode substituir toda a primeira fórmula de C1 por tudo em uma fórmula.

    

Answer 3

todas as soluções acima são incríveis; no entanto, uma boa maneira de fazer isso (Assumint Sr. John Smith está em uma coluna) é fazer tools to columns no menu Data e usar space como um delimitador

    

Answer 4

Ctrl + F, escolha substituir, coloque "Sr." (não esqueça o caractere de espaço) e substitua por deve estar vazio. Em seguida, substitua todos.
Ctrl + F, escolha substituir, coloque "Sra" (não esqueça o caractere de espaço) e substitua por deve estar vazio. Então substitua tudo.

Essa solução é rápida para poucas palavras para substituir, mas deve ser usada apenas com palavras que não estão dentro de um nome (com "James Amr. Kohn", por exemplo; neste caso, a opção "case sensitive" resolve isso) .

    

Answer 5

Eu usaria o Ctr + F e usaria a ferramenta replace, simplesmente digite a palavra que você quer remover e clique em replace - isso substituirá a palavra escolhida por nada!