Excel - Divide os valores de uma coluna em 2 colunas, divididas em cada segunda linha

Question

Eu tenho este conjunto de dados que eu quero dividir em duas colunas usando uma fórmula. Eu sei que posso usar algo como

=MOD(ROW(A1),2)

para baixo ao longo da coluna adjacente, que coloca um 1 ou 0 em cada linha que eu posso filtrar.

Gostaria de saber se existe um método mais simples usando uma fórmula?

A
B
C
D
E
F

Eu quero acabar com isso em outras duas colunas.

A  A  B
B  C  D
C  E  F
D
E
F

Eu tentei =OFFSET($A$2,2,-1) na Coluna B1 e =OFFSET($A$2,4,-1) na célula B2, arrastando para baixo não incrementa corretamente, eu preciso incrementar o "2" por 2 em cada nova linha.

    

Answer 1

Uma fórmula.

Coloque isso na cópia B1 para cima e para baixo.

=INDEX($A:$A,(ROW($A1)-1)*2+COLUMN(A$1))

Ao contrário de INDIRECT e OFFSET, isso não é volátil.

    

Answer 2

Use indiretamente.

Em B1, use esta fórmula:

=INDIRECT("A"&(ROW(B1)*2-1))

Em C1, use esta fórmula

=INDIRECT("A"&(ROW(C1)*2))

    

Answer 3

Você só precisa adicionar uma contagem de linha multiplicada por 2, no seu OFFSET,

Em B1 você pode usar:

=OFFSET($A$1,(ROWS($A$1:A1)-1)*2,0)

Em C1 você pode usar:

=OFFSET($A$2,(ROWS($A$1:A1)-1)*2,0)

Em seguida, arraste-os para baixo.