No windows: como obter a data da última modificação (hora UTC) de um arquivo com o wmic

Question

Eu escrevi o seguinte lote para obter a data da última modificação. O problema é que ele é dado no tempo do relógio e não no horário UTC. Eu sei que tenho o atraso em minutos, mas não é tão simples para fazer o deslocamento do número com o arquivo de lote. Existe um sinalizador para dar ao wmic para obter a hora UTC? Este é o arquivo em lote

@echo off 
setlocal enableextensions disabledelayedexpansion
set file=%1
set WORKINGdir=%~dp0
rem wmic wants double backslash
set PATHfile=%WORKINGdir%%file%
set PATHfile=%PATHfile:\=\%
for /f %%a in (
    'wmic  DataFile where "Name='%PATHfile%'" get lastmodified   ^| find "+" '
) do set "val=%%a"
echo %val%
rem get first 14 digits (good until year 9999)
echo %val:~0,14%
endlocal

Isso me dá essa saída:

20161026144823.620815+120
20161026144823

    

Answer 1

Na verdade, a aritmética de timestamp é uma dor. Ajustar a hora para UTC pode resultar em uma data diferente, o que significa que você pode ter que se preocupar com quantos dias no mês e talvez precise se preocupar com anos bissextos.

O WMIC não possui nenhuma disposição interna para formatar o registro de data e hora como UTC. E lote certamente não tem praticamente nenhum suporte para lidar com aritmética de data / hora.

Eu escrevi um utilitário chamado JREN.BAT que pode resolver sua problema facilmente. Foi escrito principalmente para permitir renomear arquivos / pastas usando expressões regulares. Mas tem funcionalidades extras que podem resolver este problema.

O JREN.BAT é um script puro (lote híbrido / JScript) que é executado nativamente em qualquer máquina Windows do XP em diante - não é necessário nenhum arquivo exe de terceiros. A documentação completa está disponível executando jren /? no prompt de comando (ou jren /?? para ajuda paginada)

O seguinte fornecerá a mesma funcionalidade do seu script, exceto que exibirá corretamente o registro de data e hora como UTC.

@echo off
for /f "delims=" %%A in (
  'jren "^.*" "ts({dt:'modified',tz:0})" /j /list /p "%~dp0" /fm %1'
) do set "ts=%%A"
echo %ts%

A saída estará no formato ISO 8601, sem pontuação, que será classificada corretamente em ordem cronológica usando a semântica de string. Algo como 20161006T155621.746+0000 .

Você pode adicionar facilmente a opção fmt: à chamada ts () para formatar o registro de data e hora da maneira que achar melhor. Use jren /?ts() para obter ajuda completa sobre todas as opções disponíveis para trabalhar com registros de data e hora.

É muito simples usar o JREN para fornecer uma lista completa de diretórios com os horários UTC.

As listas a seguir modificam a data e hora, o tamanho e o nome do arquivo para todos os arquivos .txt que começam com t no diretório atual.

D:\test>jren "^.*" "ts({dt:'modified',tz:0,fmt:'{iso-dt}  {iso-tm}'})+size('              ')+'  '+$0" /j /list /fm t*.txt
2015-06-22  19:11:22.134            74  temp1.txt
2015-06-22  19:11:22.259             0  temp2.txt
2015-06-22  19:11:22.384             0  temp3.txt
2016-09-07  15:20:08.146         10376  tempfile.txt
2016-10-06  15:56:21.746            14  test.txt
2015-06-22  19:11:23.600           342  text2.txt
2015-06-22  19:11:23.741           288  textfile1.txt
2015-06-22  19:11:23.866           144  textfile2.txt
2015-10-19  19:12:16.441           707  TL.txt
2016-01-13  17:35:17.505          1030  tl64.txt
2016-01-13  17:36:48.501           974  tl64_2.txt
2016-01-13  17:45:16.383           943  tl64_3.txt
2016-01-13  17:37:21.308           707  tl_1.txt
2016-01-13  17:37:30.356           707  tl_2.txt
2016-01-13  17:45:50.469           707  tl_3.txt
2015-06-22  19:11:24.006            42  tmp.txt
2015-06-22  19:11:24.427        541553  toc-z.txt
2015-08-31  20:59:25.202      17442083  tree.txt
2015-06-22  19:11:24.583           304  tsc_call_layout.txt

O JREN usa o WMI para obter o último registro de data e hora modificado, o que é bastante lento. Dependendo da sua configuração de idioma, você poderá usar fsomodified , em vez de modified , para obter o registro de data e hora usando o FileSystemObject. Isso é muito mais rápido, mas não fornece milissegundos, e só funciona se o seu idioma formatar cadeias de registro de data e hora de uma maneira que possa ser interpretada pelo objeto de data do JScript.

D:\test>jren "^.*" "ts({dt:'fsomodified',tz:0,fmt:'{iso-dt}  {hh}:{nn}:{ss}'})+size('              ')+'  '+$0" /j /list /fm t*.txt
2015-06-22  19:11:22            74  temp1.txt
2015-06-22  19:11:22             0  temp2.txt
2015-06-22  19:11:22             0  temp3.txt
2016-09-07  15:20:08         10376  tempfile.txt
2016-10-06  15:56:21            14  test.txt
2015-06-22  19:11:23           342  text2.txt
2015-06-22  19:11:23           288  textfile1.txt
2015-06-22  19:11:23           144  textfile2.txt
2015-10-19  19:12:16           707  TL.txt
2016-01-13  18:35:17          1030  tl64.txt
2016-01-13  18:36:48           974  tl64_2.txt
2016-01-13  18:45:16           943  tl64_3.txt
2016-01-13  18:37:21           707  tl_1.txt
2016-01-13  18:37:30           707  tl_2.txt
2016-01-13  18:45:50           707  tl_3.txt
2015-06-22  19:11:24            42  tmp.txt
2015-06-22  19:11:24        541553  toc-z.txt
2015-08-31  20:59:25      17442083  tree.txt
2015-06-22  19:11:24           304  tsc_call_layout.txt

    

Answer 2

é possível com lote puro, embora possa ser lento para um grande número de arquivos. As rotinas de lote são derivadas de funções da Biblioteca de Funções do Richie Lawrence Batch.

:: Demo_DateAddSecs.cmd ::::::::::::::::::::::::::::::::::::::::::::
@Echo off&cls
Call :GetISODT DateTime
Echo %DateTime% is now 
Call :DateAddSecs %DateTime% 7200 NewDT
Echo %NewDT% +7200 secs
Echo y___m_d_h_n_s_
Echo 20160101013000 Subtract 2h from new year 1:30
Call :DateAddSecs 20160101013000 -7200 NewDT
Echo %NewDT% -7200 secs
Echo y___m_d_h_n_s_
Echo 20160301013000 March first -12h this is a leap year
Call :DateAddSecs 20160301013000 -43200 NewDT
Echo %NewDT% -43200 secs
Echo y___m_d_h_n_s_
Pause
Goto :Eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:GetISODT Var
SetLocal
for /f "tokens=1-3 delims=.+-" %%A in (
  'wmic os get LocalDateTime^|findstr ^^[0-9]'
    ) do Set _IsoDT=%%A
EndLocal&Set "%1=%_IsoDT%"&Goto :Eof
:: GetISODT.cmd :::::::::::::::::::::::::::::::::::::::::::::::::::::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:DateAddSecs %yyyymmddhhnnss% %secs2Add% DTreturnvar
:: Original functions DateToSecs and SecsToDate
:: By:   Ritchie Lawrence, updated 2002-08-13. Version 1.1
:: Func: Converts DateTime to number of seconds elapsed since 
::       1st January 1970 00:00:00 adds the supplied seconds
::       and converts back to a valid Datetime
::  For a given calendar date and time of day. Tested with Win10pro.
:: Args:
::  %1 by val Datetime in the form yyyymmddhhnnss
::  %2 by val seconds integer to add/subtract 1 hour = 60*60 = 3600
::  %3 by ref the var name to receive the resulting Datetime 
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
SetLocal EnableExtensions& Set DT=%1
Set yy=%DT:~0,4%&set mm=%DT:~4,2%&set dd=%DT:~6,2%
set hh=%DT:~8,2%&set nn=%DT:~10,2%&set ss=%DT:~12,2%
Set /a dd=100%dd%%%100,mm=100%mm%%%100
Set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
Set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
if 1%hh% LSS 20 set hh=0%hh%
Set /a hh=100%hh%%%100,nn=100%nn%%%100,ss=100%ss%%%100
Set /a j=j*86400+hh*3600+nn*60+ss
Endlocal&set /A secs=%j%+%2
:: SecsToDate %secs% yy mm dd hh nn ss
SetLocal EnableExtensions
Set /a i=%secs%,ss=i%%60,i/=60,nn=i%%60,i/=60,hh=i%%24,dd=i/24,i/=24
Set /a a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
Set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2
Set /a dd/=5,dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
(if %hh% LSS 10 set hh=0%hh%)&(if %nn% LSS 10 set nn=0%nn%)
if %ss% LSS 10 set ss=0%ss%
Endlocal&set "%3=%yy%%mm%%dd%%hh%%nn%%ss%"&Goto :Eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

Dá esta saída

> DemoDateAddSecs.cmd
20161027053749 is now
20161027073749 +7200 secs
y___m_d_h_n_s_
20160101013000 Subtract 2h from new year 1:30
20151231233000 -7200 secs
y___m_d_h_n_s_
20160301013000 March first -12h this is a leap year
20160229133000 -43200 secs
y___m_d_h_n_s_

HTH