Procurando por um valor no Excel entre planilhas, se encontrado retornando valor de outra coluna

Question

Eu tenho uma pasta de trabalho que tem duas planilhas. Eu preciso de uma função que pegue um valor da coluna A na worksheet_1 e a compare à coluna D na worksheet_2. Se o valor for encontrado na coluna D na worksheet_2, exiba o conteúdo da coluna A na worksheet_2. Se não for encontrado, mostre "Não encontrado".

Na worksheet_1, tenho o seguinte conjunto de dados:

     A
1. ABC123
2. DEF234
3. GHI567
4. JKLM123
5. OPQ456
6. RSTU789

Na worksheet_2, tenho o seguinte conjunto de dados:

    A       D                             
1.  RED     ER4654F- RSTU789 - 54DF56GH
2.  BLUE    132DF- ABC123 - SDFG1665
3.  GREEN   456FD-OPQ456-D564G
4.  PURPLE  7987-DEF234-165416
5.  ORANGE  SDF86- JKLM123 -5DFG6H

Como eu estruturaria a função para procurar corretamente se os valores da worksheet_1 existem na coluna D do workseet_2 e exibir os valores da coluna A?

Agradecemos antecipadamente por sua ajuda!

    

Answer 1

Você pode usar a função CORRESP para pesquisar a Coluna D na Planilha2 do item na Coluna A da Planilha1. Por exemplo, na célula B1 da Planilha1, você poderia inserir:

=MATCH("*"&$A1&"*",Sheet2!$D:$D,0)

Isso retornará o número da linha na Coluna2 Coluna D, onde o conteúdo de A1 é encontrado, ou # N / A, se nenhuma correspondência for encontrada. O "*" antes e depois do termo de pesquisa são curingas.

Você pode usar a função INDEX para obter o conteúdo da Sheet2 Column A. Altere a célula B1 para:

=INDEX(Sheet2!$A:$A,MATCH("*"&$A1&"*",Sheet2!$D:$D,0)) 

Isso retornará o valor de Sheet2 Column A que corresponde ao item que foi encontrado na Sheet2 Column D, ou # N / A se nenhuma correspondência for encontrada.

Você pode usar a função IFERROR para mostrar "Não encontrado" quando não houver correspondência. Mude a célula B1 para

=IFERROR(INDEX(Sheet2!$A:$A,MATCH("*"&$A1&"*",Sheet2!$D:$D,0)),"Not Found")

O único problema remanescente é que usar curingas significa que você pode obter uma correspondência apenas com parte do termo na Coluna D (por exemplo, "BC12" seria encontrado na linha 2). Se não é isso que você quer, sugiro alterar a coluna D para remover os espaços e adicionar um "-" no início e no final de cada item, então a linha 1 se torna:

'-ER4654F-RSTU789-54DF56GH-

(o apóstrofo informa ao Excel para não tratar isso como um cálculo). Agora você pode adicionar um "-" antes e depois do termo de pesquisa para garantir que você corresponde apenas as coisas entre o "-" na coluna D. A fórmula final na célula B1 é:

=IFERROR(INDEX(Sheet2!$A:$A,MATCH("*-"&$A1&"-*",Sheet2!$D:$D,0)),"Not Found")

Copie esta fórmula para as outras células na Coluna B da Folha1.