Critérios SUMIF entre datas

Navegue suas respostas
0

Eu tenho Custos da planilha e Datas, o custo foi aumentado, o custo da data foi realmente recebido. O custo é formatado como moeda. Data de recebimento planejada é uma seleção suspensa e a entrada de mercadorias real é formatada como abaixo, por exemplo, 

Cost | Planned Recieve Date | Actual Goods Receipt
$XYZ | Apr-18               | 11 April 2018
$XYZ | Apr-18               | 24 April 2018
$XYZ | Apr-18               | 28 April 2018

O que estou tentando fazer é ver uma soma de todos os custos ESPERADOS a serem aumentados em um determinado mês, e quanto foi REALMENTE recebido nesse mês . Os Custos com datas estão em uma planilha "Pedidos" e a fórmula que preciso é ir em outra planilha.

Os custos esperados usam a coluna Data de recebimento planejada. Minha fórmula é: 

= SUMIF(Ordering!$L$11:$L$365, "Apr-18", Ordering!$E$11:$E$365)

O que está me causando problemas é a quantidade realmente recebida, não consigo descobrir os critérios corretamente. Isso usa a coluna "Bom recebimento real", que tem uma data formatada. A célula exibe 24 de abril de 2018 e tem 24/04/2018 na caixa do editor de célula. A fórmula que usei é: 

= SUMIF(Ordering!$P$11:$P$365,">=01/04/2018 AND <=30/04/2018",Ordering!$M$11:$M$365)

Isso me dá um valor ABAIXO do que eu espero, sem perder custos. (só tenho 3 para o omnth de abril.) Eu tentei várias maneiras diferentes de escrever meus critérios, e usei curingas.

Qual é a maneira correta de construir meus critérios para que eu possa ver o custo total do ACTUAL RECIEVED para todas as datas dentro de um determinado mês?

    
por Thom G 18.09.2018 / 13:06

2 respostas

1

você pode usar a fórmula do Sumproduct: 

=SUMPRODUCT((MONTH(A2:A10)=4)*(MONTH(A2:A10)=4), (B2:B10))
  • A2: A10 é um intervalo de datas;
  • 4 é o número do mês (abril);
  • B2: B10 é um intervalo em que seus preços são
por 18.09.2018 / 15:10
1

Codificando a fórmula 

=SUMIFS(B2:B10,A2:A10,">=01/04/18",A2:A10,"<=30/04/18")

Opção 1 - inserindo manualmente a data na fórmula 

=SUMIFS(B2:B10,A2:A10,">="&DATE(2018,4,1),A2:A10,"<="&DATE(2018,4,30))

Opção 2 - Referenciando uma data em uma célula 

Start Date in G1
End Date in G2

=SUMIFS(B2:B10,A2:A10,">="&$G$1,A2:A10,"<="&$G$2)

Opção 3 - Retornando um período de 1 mês com base no mês em uma referência de célula 

Date reference in G1

=SUMIFS(B2:B10,A2:A10,">="&EOMONTH($G$1,-1)+1,A2:A10,"<="&EOMONTH($G$1,0))
    
por 18.09.2018 / 16:50

Tags

Selecione no Excel uma célula para a qual o índice da linha está em A1 e o índice da coluna está em A2 Como alterar as teclas de atalho do programa? (Whatsapp)