Conteúdo da pasta de e-mail através do AppleScript

Question

Estou tentando escrever um AppleScript que envia por e-mail todos os arquivos da pasta especificada. Funciona como esperado quando há apenas um arquivo, mas não quando há mais de um. Isso só me dá esse erro:

"Mail got an error: Can’t make {alias \"Macintosh HD:Users:me:temp_photos:IMG_2902.JPG\", alias \"Macintosh HD:Users:me:temp_photos:IMG_2903.JPG\"} into type file." number -1700 from {alias "Macintosh HD:Users:me:temp_photos:IMG_2902.JPG", alias "Macintosh HD:Users:me:temp_photos:IMG_2903.JPG"} to file

Aqui está o meu AppleScript

    tell application "Finder"
    set attchList to (every item of TempPhotos) as alias list
end tell

set theSender to "Me<[email protected]>"
set recipName to "You"
set recipAddress to "[email protected]"

tell application "Mail"

    set newmessage to make new outgoing message with properties {subject:"Important File Attachment", content:msgText & return & return, visible:false}
    tell newmessage
        set visible to false
        set sender to theSender
        make new to recipient with properties {name:recipName, address:recipAddress}
        make new attachment with properties {file name:attchList} at after the last paragraph

    end tell
    send newmessage
end tell

Alguma ajuda, por favor?

    

Answer 1

Tente:

--For Demo  
set TempPhotos to (choose folder)
set msgText to "My Test"

tell application "Finder" to set attchList to (every item of TempPhotos) as alias list

set theSender to "Me<[email protected]>"
set recipName to "You"
set recipAddress to "[email protected]"

tell application "Mail"

    set newmessage to make new outgoing message with properties {subject:"Important File Attachment", content:msgText & return & return, visible:false}
    tell newmessage
        set visible to false
        set sender to theSender
        make new to recipient with properties {name:recipName, address:recipAddress}
        repeat with attach in attchList
            make new attachment with properties {file name:(contents of attach)}
        end repeat

        --For Demo  
        set visible to true
    end tell
    --send newmessage
end tell