zsh HISTFILE - ainda lido de ~ / .zsh_history

Question

Eu configurei meu $HISTFILE env var para algo customizado, e meu zsh está realmente gravando no novo histfile.

Mas ao usar a seta para cima ou outros recursos de pesquisa de histórico, ainda lê de ~ / .zsh_history .

Ou seja, se eu abrir um novo shell e pressionar a seta para cima diretamente, receberei a última linha gravada em ~/.zsh_history : (

Eu uso oh-my-zsh (com osx brew celery gem git-flow npm pip screen vi-mode last-working-dir docker ), e aqui estão os ajustes que eu uso:

# zsh options
#Initial
setopt appendhistory autocd beep extendedglob nomatch notify
#history
HISTSIZE=100000000
SAVEHIST=100000000
setopt HIST_IGNORE_SPACE
setopt extended_history
setopt hist_expire_dups_first
setopt hist_ignore_dups # ignore duplication command history list
setopt hist_ignore_space
setopt hist_verify
setopt inc_append_history
setopt share_history # share command history data
#dirs
setopt autopushd pushdminus pushdsilent pushdtohome pushdignoredups
setopt auto_name_dirs
#appearance
setopt multios
setopt cdablevarS
setopt prompt_subst
#misc
setopt long_list_jobs
#correction
setopt correct_all
#completion
setopt auto_menu         # show completion menu on succesive tab press
setopt complete_in_word
setopt completealiases
setopt always_to_end
#syml
setopt chaselinks
#stop pissing me off when using ! in line
unsetopt banghist    

# The following lines were added by compinstall
zstyle :compinstall filename '/Users/alex/.zshrc'

# Already in ohmyzsh
#autoload -Uz compinit
#compinit
# End of lines added by compinstall

########
# Key bindings, vi, etc.
autoload -U edit-command-line
zle -N edit-command-line
bindkey -M vicmd 'v' edit-command-line

# create a zkbd compatible hash;
# to add other keys to this hash, see: man 5 terminfo
typeset -A key

key[Home]=${terminfo[khome]}
key[BackSpace]=${terminfo[kbs]}
key[End]=${terminfo[kend]}
key[Insert]=${terminfo[kich1]}
key[Delete]=${terminfo[kdch1]}
key[Up]=${terminfo[kcuu1]}
key[Down]=${terminfo[kcud1]}
key[Left]=${terminfo[kcub1]}
key[Right]=${terminfo[kcuf1]}
key[PageUp]=${terminfo[kpp]}
key[PageDown]=${terminfo[knp]}

# setup key accordingly
[[ -n "${key[Home]}"    ]]  && bindkey  "${key[Home]}"    beginning-of-line
[[ -n "${key[BackSpace]}" ]]  &&  bindkey "${key[BackSpace]}" backward-delete-char
[[ -n "${key[BackSpace]}" ]] &&  bindkey -M vicmd "${key[BackSpace]}" backward-delete-char
bindkey '^H' backward-delete-char
bindkey -M vicmd '^H' backward-delete-char
bindkey "^?" backward-delete-char
bindkey -M vicmd "^?" backward-delete-char
[[ -n "${key[End]}"     ]]  && bindkey  "${key[End]}"     end-of-line
[[ -n "${key[Insert]}"  ]]  && bindkey  "${key[Insert]}"  overwrite-mode
[[ -n "${key[Delete]}"  ]]  && bindkey  "${key[Delete]}"  delete-char
[[ -n "${key[Delete]}"  ]]  && bindkey -M vicmd "${key[Delete]}"  delete-char

[[ -n "${key[Left]}"    ]]  && bindkey  "${key[Left]}"    backward-char
[[ -n "${key[Right]}"   ]]  && bindkey  "${key[Right]}"   forward-char

[[ -n "${key[Up]}"   ]]  && bindkey  "${key[Up]}"    history-beginning-search-backward && bindkey -M vicmd "${key[Up]}"    history-beginning-search-backward
[[ -n "${key[Down]}" ]]  && bindkey  "${key[Down]}"  history-beginning-search-forward && bindkey -M vicmd "${key[Down]}"  history-beginning-search-forward

bindkey -M vicmd 'h'  backward-char
bindkey -M vicmd 'l'  forward-char
bindkey -M vicmd '^R' redo
bindkey -M vicmd 'u'  undo
bindkey -M vicmd 'ga' what-cursor-position
bindkey -M vicmd 'v'  edit-command-line


# Finally, make sure the terminal is in application mode, when zle is
# active. Only then are the values from $terminfo valid.
if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
    function zle-line-init () {
        printf '%s' "${terminfo[smkx]}"
    }
    function zle-line-finish () {
        printf '%s' "${terminfo[rmkx]}"
    }
    zle -N zle-line-init
    zle -N zle-line-finish
fi

    

Answer 1

A configuração de HISTFILE em sua configuração zsh deve mudar para onde o histórico é escrito e de onde ele é lido. É provável que oh-my-zsh defina HISTFILE=~/.zsh_history antes de você configurá-lo, caso em que o histórico já foi lido em ~/.zsh_history .

Olhando para o código oh-my-zsh , existem duas maneiras de resolver isso:

• defina HISTFILE antes de carregar oh-my-zsh . Ou seja, tem que ser definido no seu ~/.zshrc antes da linha que contém

  source $ZSH/oh-my-zsh.sh
  

  Esta seria uma solução simples, se você quiser alterar apenas HISTFILE .

• sobrecarregue o módulo history.zsh com sua própria versão personalizada. Oh-my-zsh carrega todos os arquivos correspondentes a $ZSH/lib/*.zsh (onde $ZSH geralmente é ~/.oh-my-zsh ) na inicialização, a menos que ${ZSH_CUSTOM}/lib/ seja um arquivo com o mesmo nome ( ZSH_CUSTOM normalmente é $ZSH/custom ). As configurações do histórico podem ser encontradas em $ZSH/lib/history.zsh e, portanto, podem ser substituídas por ${ZSH_CUSTOM}/lib/history.zsh .

  Se você quiser alterar mais as configurações encontradas em $ZSH/lib/history.zsh , esse provavelmente é o caminho a seguir. Caso contrário, você teria que definir HISTFILE antes de carregar oh-my-zsh e tudo mais depois.

Uma maneira de alterar HISTFILE (temporariamente) depois em uma sessão de shell é

fc -p /path/to/new_history

Isso coloca o histórico atual em uma pilha, define HISTFILE=/path/to/new_history e lê o histórico desse arquivo (se existir). Quaisquer novos comandos também serão gravados no novo HISTFILE . Você pode voltar para o histórico original com fc -P .