#!/usr/bin/perl
use strict;
use Sort::Naturally; # CPAN module to perform Natural Sorts.
# should do real option/argument processing here. this is good enough
# for this example.
my $params = shift || 'params.txt';
my $strings = shift || 'strings.txt';
my %params=(); # hash to hold each parameter
# read in the parameters file.
open(PARAMS,"<",$params) || die "couldn't open $params: $!";
while(<PARAMS>) {
# clean up input, discard everything that would complicate splitting
# into comma-separated fields.
s/^\s*\{\s*parameter\s+//;
s/\s*;\s*\}//;
s/^\s*|\s*$//g;
s/\s*,$//; # / this comment fixes stack exchange\'s broken syntax colouring
chomp;
# split each input line into an array, with comma as separator
my @F = split /\s*,\s*/; # /
# use each array element to populate the %params hash
foreach my $f (@F) {
my ($key,$val) = split /\s*=\s*/, $f; # /
$params{$key} = $val;
};
};
close(PARAMS);
# read in the strings file and apply changes to %params
# this assumes that the strings file contains new values for
# all paramaters and that they are listed one-per-line in order (0..35)
open(STRING,"<",$strings) || die "couldn't open $strings: $!";
my $lineno = 0;
while(<STRING>) {
s/^\s*|\s*$//g; # remove leading/trailing whitespace
s/#.*//; # ignore comments
next if (/^$/);
$params{'S'.$lineno++} = "7'd$_";
};
close(STRING);
# natural-sort %params keys
my @keys = nsort(keys %params);
print '{ parameter ', join(', ', map { $_ = "$_=$params{$_}" } @keys ), "; }\n";
salve como, por exemplo, change-params.pl , torne executável com chmod +x e execute como:
$ ./change-params.pl [parameter-file [strings-file]]
Exemplo de saída:
$ ./change-params.pl | fmt
{ parameter S0=7'd10, S1=7'd5, S2=7'd30, S3=7'd3, S4=7'd4, S5=7'd5,
S6=7'd6, S7=7'd7, S8=7'd8, S9=7'd9, S10=7'd10, S11=7'd11, S12=7'd12,
S13=7'd13, S14=7'd14, S15=7'd15, S16=7'd16, S17=7'd17, S18=7'd18,
S19=7'd19, S20=7'd20, S21=7'd21, S22=7'd22, S23=7'd23, S24=7'd24,
S25=7'd25, S26=7'd26, S27=7'd27, S28=7'd28, S29=7'd29, S30=7'd30,
S31=7'd31, S32=7'd32, S33=7'd33, S34=7'd34, S35=7'd35; }
(Nota: meu strings.txt contém apenas os 3 valores que você mencionou, então ele só muda S0, S1 e S2. Todos os outros valores nos parâmetros não mudam)
Isso constrói um hash ( %params ) para conter todos os valores no arquivo de parâmetros. Em seguida, ele lê um novo conjunto de valores para cada elemento de% params do arquivo "strings". Finalmente, ele imprime o hash% params (no mesmo formato em que foi lido) na ordem ordenada natural.
Os arquivos a ler podem ser especificados na linha de comando (como argumentos 1 e 2). Eles assumem como padrão params.txt e strings.txt .
O script assume que o arquivo de strings tem um valor atualizado por linha. Se for espaço em branco ou separado por vírgula, você poderá dividir cada linha de entrada em uma matriz e iterar sobre ela, semelhante ao código usado para ler o arquivo de parâmetros. Você teria que acompanhar a contagem de campo conforme cada campo é usado, em vez da contagem de linhas usada acima.
O script não quebra linhas longas, porque isso pode ser facilmente alcançado com ferramentas como fmt ou par . por exemplo. ./change-params.pl | fmt como usei acima.